mandelbrox {
;2D mandelbox with mandelbrot. DOES NOT WORK WITH SMOOTH COLORING
init:
  z = @start
  float re = real(z)
  float im = imag(z)
  float r2 = @r*@r
  float ir2 = 1/(@r*@r)
  float reP = real(#pixel);
  float imP = imag(#pixel);
  float reS = real(@s);
  float imS = imag(@s);
  float reF = real(@f);
  float imF = imag(@f);
loop:
  ;first do a box fold:
  if re>1,
     re = 2-re
  elseif re<-1,
     re = -2-re
  endif
  if im>1,
     im = 2-im
  elseif im<-1,
     im = -2-im
  endif

  ;multiply by f:
  ;(re+1i*im)*(reF+1i*imF)
  float re_tmp = re*reF-im*imF;
  im = re*imF+im*reF
  re = re_tmp

  ;do a ball fold:
  float m2 = re*re+im*im
  if m2<r2, ;devide by r^2.
      re = re*ir2
      im = im*ir2
  elseif m2<1,
      re = re/m2; m = m/1: invert magnitude.
      im = im/m2
  endif
  ;multiply by s
  re_tmp = re*reS-im*imS
  im = re*imS+im*reS
  re = re_tmp

  ;finally, multiply by z^2 and add the "c":
  re_tmp = re*re-im*im + reP
  im = 2*re*im + imP
  re = re_tmp
bailout:
  re*re+im*im <= @bailout;
default:
  title = "mandelbrox"
  center = (0, 0)
  magn=0.5
  maxiter = 3000;
  periodicity = 0;
  complex param s
    caption = "Mandelbox s"
    default = 2
  endparam
  float param r
    caption = "Mandelbox r (1.0 is nicer than 0.5, no branch points.)"
    default = 1.0
  endparam
  complex param f
    caption = "Mandelbox f (0.8 is nicer than 1)"
    default = 0.8
  endparam
  float param bailout
    caption = "Bailout value"
    default = 65536
$IFDEF VER40
    exponential = true
$ENDIF

  endparam
switch:
  type = "mandelbroxJulia"
  seed = #pixel
  s = s
  r = r
  f = f
  bailout = bailout
}

mandelbroxJulia {
;2D mandelbox with mandelbrot (julia). DOES NOT WORK WITH SMOOTH COLORING
init:
  z = #pixel
  float re = real(z)
  float im = imag(z)
  float r2 = @r*@r
  float ir2 = 1/(@r*@r)
  float reS = real(@s);
  float imS = imag(@s);
  float reF = real(@f);
  float imF = imag(@f);
loop:
  ;first do a box fold:
  if re>1,
     re = 2-re
  elseif re<-1,
     re = -2-re
  endif
  if im>1,
     im = 2-im
  elseif im<-1,
     im = -2-im
  endif

  ;multiply by f:
  ;(re+1i*im)*(reF+1i*imF)
  float re_tmp = re*reF-im*imF;
  im = re*imF+im*reF
  re = re_tmp

  ;do a ball fold:
  float m2 = re*re+im*im
  if m2<r2, ;devide by r^2.
      re = re*ir2
      im = im*ir2
  elseif m2<1,
      re = re/m2; m = m/1: invert magnitude.
      im = im/m2
  endif
  ;multiply by s
  re_tmp = re*reS-im*imS
  im = re*imS+im*reS
  re = re_tmp

  ;finally, multiply by z^2 and add the "z":
  re_tmp = re*re-im*im + real(@seed)
  im = 2*re*im + imag(@seed)
  re = re_tmp
bailout:
  re*re+im*im <= @bailout;
default:
  title = "mandelbrox (julia)"
  center = (0, 0)
  magn=0.5
  maxiter = 3000;
  periodicity = 0;
  complex param s
    caption = "Mandelbox s"
    default = 2
  endparam
  float param r
    caption = "Mandelbox r (1.0 is nicer than 0.5, no branch points.)"
    default = 1.0
  endparam
  complex param f
    caption = "Mandelbox f (0.8 is nicer than 1)"
    default = 0.8
  endparam
  complex param seed
    caption = "Julia seed"
    default = (0,0)
  endparam
  float param bailout
    caption = "Bailout value"
    default = 65536
$IFDEF VER40
    exponential = true
$ENDIF

  endparam
}